Stata：如何正确检验U型关系的存在
👇 连享会 · 推文导航 | www.lianxh.cn
🍎 Stata：Stata基础 | Stata绘图 | Stata程序 | Stata新命令 📘 论文：数据处理 | 结果输出 | 论文写作 | 数据分享 💹 计量：回归分析 | 交乘项-调节 | IV-GMM | 时间序列 | 面板数据 | 空间计量 | Probit-Logit | 分位数回归 ⛳ 专题：SFA-DEA | 生存分析 | 爬虫 | 机器学习 | 文本分析 🔃 因果：DID | RDD | 因果推断 | 合成控制法 | PSM-Matching 🔨 工具：工具软件 | Markdown | Python-R-Stata 🎧 课程：公开课-直播 | 计量专题 | 关于连享会
作者：韩文轩 (广西大学)
邮箱：WX_Han1206@163.com
编者按：本文主要摘译自下文，特此致谢！
Source：Simonsohn U, Nelson L. Thirty-somethings are shrinking and other U-shaped challenges. 2014. -Link-
目录
1. 引言
2. 传统倒 U 型关系的检验方法
2.1 检验方法
2.2 检验方法的不足之处
3. 基于二次回归确定倒 U 型的检验方法
4. Stata 实例
5. 参考文献
6. 相关推文
温馨提示： 文中链接在微信中无法生效。请点击底部「阅读原文」。或直接长按/扫描如下二维码，直达原文：
1. 引言
在实证研究中，倒 U 型关系是非线性关系中较为常见的一种关系。为了验证倒 U 型关系的存在，研究人员在回归模型中加入解释变量的平方项，并通过二次项系数是否显著、以及二次项系数与一次项系数是否异号确定倒 U 型关系。
实际上，这种方法存在一定的缺陷。为了解决这个问题，Simonsohn 和 Nelson (2014) 提出了一种改进方法来确定倒 U 型关系的存在。本文的主要目的是介绍这种方法并结合案例加以说明。
2. 传统倒 U 型关系的检验方法
2.1 检验方法
关于倒 U 型关系，很多文献都是按照以下四个步骤进行检验：
构造回归模型 ，进行普通的线性回归； 在回归模型中加入平方项，即 ，进行二次回归； 根据回归结果判断回归模型中二次项系数 的显著性。如果 显著，且 与 异号，那么倒 U 型关系存在； 绘制图像进行辅助验证。
以 Swaab 等 (2014) 的论文为例，该研究发现在 NBA 比赛中，球队天赋与球队表现之间存在倒 U 型关系。起初，球队表现随着球队中天赋球员的增加而提升，在到达某一点后，球队表现却随着天赋球员的增加而变差。
上图报告了 NBA 比赛中球员天赋对球队表现回归结果。在 Model1 中，作者先进行了普通的线性回归，回归结果显示球队表现与球队天赋的线性关系是正向且显著的。在 Model 2 中，作者在回归模型中加入解释变量的平方项。回归结果显示 Talent 和 Talent-squard 的回归系数异号且显著。因此，作者推断在 NBA 比赛中，球队天赋和球队表现之间存在倒U型关系。
为了增强说服力，作者还绘制图像进行辅助验证。上图展示了球员天赋与球队表现的拟合曲线。
2.2 检验方法的不足之处
仅依靠解释变量的二次项来判断 U 型关系是有问题的。因为 U 型关系随处可见，甚至在 U 型不存在的地方也可以看见。以身高和年龄为例：
从上图的散点来看，人的身高在一定年龄以后保持不变。但是根据拟合曲线显示，人的身高一开始随着年龄的增加而增长，在 27 岁以后人的身高会变矮，即年龄和身高之间存在倒 U 型关系。
类似的情况还有年均收入和收入者的百分位数。根据散点的分布情况可知，收入者所在的百分位越高，平均工资越高。但是从拟合的曲线来看，年均收入和收入者的百分位数是 U 型关系。
从上面两个例子，我们发现按照传统的方法检验倒 U 型关系的存在性会得出错误的结论。问题的根源是我们用回归尽可能地去接近数据 (也就是上图中蓝色的点)，但是却忽略了变量之间隐含的真实关系。因此，U 型关系能够推出解释变量的二次项系数显著，但是解释变量的二次项系数显著不能推出 U 型关系。
当然，绘图能够避免这类问题的出现。但是绘图只是必要手段，它不能有效地推导出倒 U 型关系。因为有时候，如果数据太少或者太多，也不能帮助我们判断 U 型关系是否存在。
以上图为例，左右两幅图分别代表了数据过多和过少的情形，这些图可能暗含 U 型关系，但是我们很难分辨平方项是否为干扰项。
在大量数据的基础上，我们希望说：“正如预测的那样，被解释变量和解释变量是 U 型关系，=0.002”。但是我们并不能从上图直接推导出这样的结论。因此，我们需要一种更为简单有效的方法能够基于二次回归确定倒 U 型关系的存在。
关于传统倒 U 型检验方法的更多问题，详见连享会推文「平方项=倒U型」。
3. 基于二次回归确定倒 U 型的检验方法
检验倒 U 型关系的基本思想是：起初 随 的增加而增加，但最终 随 的增大而减少。基本步骤如下：
根据原始数据绘制图形； 进行二次回归 ，通过回归结果判断 和 的值是否异号且显著； 寻找断点：如果 和 的值异号且显著，我们找到 U 型达到最大时的 值，记该点为 。由于检验方法是基于二次回归进行的，； 创建新的变量：生成 、 和 三个新的变量。变量具体定义如下：
进行断点回归：。如果 和 异号且显著，那么 和 存在倒 U 型关系； 绘制图像辅助验证。
4. Stata 实例
Aghion 等 (2005) 研究了竞争与创新的 U 型关系。在这里，我们将以这篇论文的数据例，重新检验竞争与创新的倒 U 型关系。
. lxhuse abbgh_data.dta, clear
. /*
> patcw 被解释变量 Innovation
> Lc 解释变量 Competition
> yr* 是年份固定效应
> iii* 是行业固定效应
> */
. global Xex "yr* iii*"
Step 1：画出图像
. egen p10 = pctile(patcw), p(10)
. egen p90 = pctile(patcw), p(90)
. sort Lc
. twoway scatter patcw Lc if patcw<p90&patcw>p10, ///
> xlabel(0.85(0.05)1.00) ylabel(0(5)20) ///
> xtitle("Competition(1-Lerner)") ytitle("Innovation(# of Patents)") ///
> msymbol(oh) mcolor(gray) || qfit patcw Lc
从上图中的散点和拟合曲线来看，被解释变量创新和解释变量竞争之间是非线性关系。其中拟合曲线的形状类似倒 U 型，但是仅仅依靠图像判定倒 U 型关系并不可靠。因此，我们在回归模型中加入平方项并进行进一步的检验。
Step 2：进行二次回归
. poisson patcw Lc Lc_2 $Xex
Poisson regression Number of obs = 354
LR chi2(39) = 2804.51
Prob > chi2 = 0.0000
Log likelihood = -734.48398 Pseudo R2 = 0.6563
------------------------------------------------------------------------------
patcw | Coefficient Std. err. z P>|z| [95% conf. interval]
-------------+----------------------------------------------------------------
Lc | 387.463 67.741 5.72 0.000 254.693 520.233
Lc_2 | -204.549 36.169 -5.66 0.000 -275.439 -133.659
yr1 | 0.211 0.136 1.56 0.120 -0.055 0.477
(omitted)
iii16 | -3.804 0.408 -9.33 0.000 -4.603 -3.004
_cons | -180.858 31.733 -5.70 0.000 -243.053 -118.662
------------------------------------------------------------------------------
. gen curveindyear = exp(_b[_cons] + _b[Lc]*Lc + _b[Lc_2]*Lc_2 )
. lab var curveindyear "Fitted exponential quadratic"
由回归结果可知，Lc 和 Lc_2 的回归系数分别为 387.463 和 -204.549，回归系数异号且显著。我们可以初步判定创新和竞争之间存在倒 U 型关系，但仍然需要进行后续检验。
Step 3：找到倒 U 型曲线的最大值点
. gen a =_b[Lc]
. gen b =_b[Lc_2]
. gen Lcmax=-a/(2*b)
Step 4：在 处产生新的预测值
. gen Lclow=0
. replace Lclow=Lc-Lcmax if Lc<Lcmax
. gen Lchigh=0
. replace Lchigh=Lc-Lcmax if Lc>Lcmax
. gen high=0
. replace high=1 if Lc>Lcmax
Step 5：进行断点回归
. poisson patcw Lclow Lchigh high $Xex
Poisson regression Number of obs = 354
LR chi2(40) = 2797.51
Prob > chi2 = 0.0000
Log likelihood = -737.98783 Pseudo R2 = 0.6546
------------------------------------------------------------------------------
patcw | Coefficient Std. err. z P>|z| [95% conf. interval]
-------------+----------------------------------------------------------------
Lclow | 9.041 2.440 3.71 0.000 4.259 13.822
Lchigh | -9.778 3.333 -2.93 0.003 -16.310 -3.246
high | 0.080 0.078 1.04 0.300 -0.072 0.232
yr1 | 0.210 0.136 1.54 0.124 -0.058 0.477
(omitted)
iii16 | -3.798 0.408 -9.31 0.000 -4.597 -2.998
_cons | 2.651 0.126 21.02 0.000 2.404 2.899
------------------------------------------------------------------------------
. gen curvex=exp(_b[_cons] + _b[Lclow]*Lclow + _b[Lchigh]*Lchigh + _b[high]*high)
. lab var curvex " Fitted interrupted regression"
由回归结果可知，Lclow 和 Lchigh 的系数分别为 9.041 和 -9.778，异号且显著，可以认为竞争和创新之间存在倒 U 型关系。
Step 6：绘制图像
. twoway scatter patcw Lc if patcw<p90&patcw>p10, ///
> xlabel(0.85(0.05)1.00) ylabel(0(5)20) ///
> xtitle("Competition(1-Lerner)") ytitle("Innovation(# of Patents)") ///
> msymbol(oh) mcolor(gray) title("Citation weighted patents") ///
> xline(0.9471159, lpattern(dash) lcolor(green)) ///
> || line curveindyear Lc, color(blue) || line curvex Lc, color(red)
综合断点回归结果和图像，我们可以确认，在数据范围内竞争和创新之间存在倒 U 型关系。
5. 参考文献
Simonsohn U, Nelson L. Thirty-somethings are shrinking and other U-shaped challenges. 2014. -Link- Swaab R I, Schaerer M, Anicich E M, et al. The too-much-talent effect: Team interdependence determines when more talent is too much or not enough[J]. Psychological Science, 2014, 25(8): 1581-1591. -PDF- Aghion P, Bloom N, Blundell R, et al. Competition and innovation: An inverted-U relationship[J]. The quarterly journal of economics, 2005, 120(2): 701-728. -PDF-
6. 相关推文
Note：产生如下推文列表的 Stata 命令为：
lianxh U型, m
安装最新版lianxh命令：
ssc install lianxh, replace
专题：断点回归RDD 倒U型+RDD：利用断点回归检验 U 形关系 专题：交乘项-调节 追本溯源，U型关系你用对了么？ utest：检验U型和倒U形关系 平方项 = 倒U型 ？
New！ Stata 搜索神器：
lianxh和songblGIF 动图介绍
搜： 推文、数据分享、期刊论文、重现代码 ……
👉 安装：
. ssc install lianxh
. ssc install songbl
👉 使用：
. lianxh DID 倍分法
. songbl all
🍏 关于我们
连享会 ( www.lianxh.cn，推文列表) 由中山大学连玉君老师团队创办，定期分享实证分析经验。 直通车： 👉【百度一下：连享会】即可直达连享会主页。亦可进一步添加 「知乎」,「b 站」,「面板数据」,「公开课」 等关键词细化搜索。